# Maintainer: Shlomi Fish <shlomif@cpan.org>
pkgbase=python-black_hole_solver-git
pkgname=('python-black_hole_solver-git' 'python2-black_hole_solver-git')
_pyname=black_hole_solver
_gitname=black_hole_solver
pkgver=20170101
pkgrel=1
pkgdesc='Solve Golf and Black Hole solitaires'
arch=('any')
url='https://github.com/shlomif/black_hole_solver'
license=('BSD')
makedepends=('git' 'python' 'python2' 'python-setuptools' 'python2-setuptools')
options=(!emptydirs)
source=("git+https://github.com/shlomif/${_gitname}")
md5sums=('SKIP')

prepare() {
  cd "${srcdir}/${_gitname}"
  cp -R "${srcdir}/${_gitname}" "${srcdir}/${_gitname}-py2"
}

package_python-black_hole_solver-git() {
  depends=('python' 'python-setuptools')
  provides=('python-black_hole_solver')
  conflicts=('python-black_hole_solver')
  cd "${srcdir}/${_gitname}"
  python3 setup.py install --root="${pkgdir}/" --optimize=1
  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgbase}/LICENSE"
}

package_python2-black_hole_solver-git() {
  depends=('python2' 'python2-setuptools')
  provides=('python2-black_hole_solver')
  conflicts=('python2-black_hole_solver')
  cd "${srcdir}/${_gitname}-py2"
  python2 setup.py install --root="${pkgdir}/" --optimize=1
}

pkgver() {
  cd "${srcdir}/${_gitname}"
  git describe --long | sed -E 's/([^-]*-g)/r\1/;s/-/./g;s/^v//'
}

# vim:set ts=2 sw=2 et: